作者：TCLSHX (影子情人)
先申明,我是在chiannet 大侠的基础上弄的,很不错的方法,也只有这样的高手才想到借尸还魂,呵呵.....原先没集成功,是因为我的Win7PE精简太多,已失去Dism功能,无法集成,现在用借尸还魂的办法还真弄上了,且我已把批处理重新整理了一下,已做到全自动了,需要说明的是,我是在WIN7系统下弄的,先在一个分区内(最好能有3G以上空间),建一个WIM目录,把一个Dism功能比较全的BOOT.WIM放在其中,并把你要集成驱动的WIN7PE.WIM也放在其中,把驱动解压后放在本分区的MY_Driver目录中,把imagex.exe也放在该分区根目录,把以下的代码保存为TCL1234.CMD放在该分区根目录,接下来运行这个批处理就可以了,看着办吧,凡是前面有REM 的都是注释掉的,可以自己删除
作为替身用的boot.wim,可以把里面的所有工具全删了,这样可以减小体积,专用来做替身....
假如你用的是XP或是2003系统,首先需要安装WindowsAIK,在安装完WindowsAIK以后需要把D:\Program Files\Windows AIK\Tools\x86和D:\Program Files\Windows AIK\Tools\x86\Servicing下的exe和dll都拷贝到C:\WINDOWS\system32下面,这一步工作要在PE下进行才好,要不会有些文件无法覆盖.那么运行下面的指令时会出错,Windows AIK自己搜来下,名称是KB3AIK_CN.iso,安装时不需要安装到C盘,因为文件可能会比较大,会造成C盘文件很多,我是安装到D盘
上面的工作做完后, 其实可以删除整个Windows AIK安装目录,不影响集成驱动的操作,我试过了,记住:是删除,不是卸载哈.
其实不只是用于集成USB3.0驱动到Win7PE,集成其它驱动到Win7PE也是可以的......
以下是可在Win7系统,也可在XP或2003系统下运行的改进版代码,复制后保存为TCL1234.CMD
@Echo Off
COLOR 2F
cd /d "%~dp0"
Set RP=
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\TCL1234.CMD Set RP=%%I:
If "%RP%"=="" Goto HDRPErr
If Exist %RP%\7pe RD %RP%\7pe /S /Q>NUL 2>NUL
If Exist %RP%\boot RD %RP%\boot /S /Q>NUL 2>NUL
md %RP%\7pe
md %RP%\boot
CLS
Echo.
ECHO 正在挂载WIM镜像......
Echo.
Dism /Mount-Wim /WimFile:%RP%\wim\WIN7PE.WIM /index:1 /MountDir:%RP%\7pe
Dism /Mount-Wim /WimFile:%RP%\wim\boot.wim /index:1 /MountDir:%RP%\boot
CLS
Echo.
ECHO 挂载WIM镜像完成,按任意键继续......
Echo.
Pause >nul
CLS
Echo.
ECHO 请耐心等候......
rd %RP%\boot\windows\inf /s /q
rd %RP%\boot\windows\system32\drivers /s /q
rd %RP%\boot\windows\system32\config /s /q
rd %RP%\boot\windows\system32\DriverStore /s /q
move "%RP%\7pe\windows\inf" %RP%\boot\windows\
move "%RP%\7pe\windows\system32\drivers" %RP%\boot\windows\system32\
move "%RP%\7pe\windows\system32\config" %RP%\boot\windows\system32\
move "%RP%\7pe\windows\system32\DriverStore" %RP%\boot\windows\system32\
If Exist %RP%\TCL1 RD %RP%\TCL1 /S /Q>NUL 2>NUL
MD %RP%\TCL1
COPY %RP%\boot\windows\system32\*.DLL %RP%\TCL1
CLS
Echo.
ECHO 确认驱动文件,即inf,sys,cat等文件全在MY_Driver目录中
Echo.
ECHO 按任意键开始集成驱动文件......
Pause >nul
Dism /Image:%RP%\boot /Add-Driver /Driver:%RP%\MY_Driver /recurse /ForceUnsigned
ECHO 按任意键继续......
Pause >nul
CLS
Echo.
move "%RP%\boot\windows\inf" %RP%\7pe\windows\
move "%RP%\boot\windows\system32\config" %RP%\7pe\windows\system32\
move "%RP%\boot\windows\system32\drivers" %RP%\7pe\windows\system32\
move "%RP%\boot\windows\system32\DriverStore" %RP%\7pe\windows\system32\
del "%RP%\7pe\windows\system32\*.pnf" /s /q
del "%RP%\7pe\windows\system32\config\*.log?" /s /q /a:h
del "%RP%\7pe\windows\inf\*.log" /q
del "%RP%\7pe\windows\system32\config\*.blf" /s /q /a:h
del "%RP%\7pe\windows\system32\config\*.regtrans-ms" /s /q /a:h
del "%RP%\7pe\Windows\System32\DriverStore\*.1" /q
for /f "delims=" %%a in ('dir /a-d /b %RP%\boot\windows\system32\*.dll') do (
if not exist "%RP%\TCL1\%%a" copy /y "%RP%\boot\windows\system32\%%a" "%RP%\7pe\windows\system32\"
)
CLS
Echo.
If Exist %RP%\WIN7 RD %RP%\WIN7 /S /Q>NUL 2>NUL
MD %RP%\WIN7
move "%RP%\7pe\Users" %RP%\WIN7\
move "%RP%\7pe\windows" %RP%\WIN7\
move "%RP%\7pe\Program Files" %RP%\WIN7\
Echo.
Echo.
ECHO 按任意键开始卸载WIM镜像文件....
Pause >nul
CLS
Echo.
ECHO 正在卸载WIM镜像文件,请稍候....
Echo.
Dism /unmount-Wim /MountDir:"%RP%\7pe" /discard
Dism /unmount-Wim /MountDir:"%RP%\boot" /discard
Echo.
ECHO 卸载WIM镜像文件完成,按任意键开始进行Win7PE.WIM打包....
Pause >nul
rd %RP%\7pe /s /q
rd %RP%\boot /s /q
rd %RP%\TCL1 /s /q
GOTO 111
:HDRPErr
ECHO 出错啦,本批处理名称不能随便改的,按任意键退出......请改回TCL1234.CMD
Pause >nul
EXIT
:111
Start /Wait imagex /capture %RP%\WIN7 "%RP%\WIN7PE.WIM" "PE" /boot /compress maximum
rd %RP%\WIN7 /s /q
CLS
Echo.
ECHO 集成驱动成功啦,WIN7PE.WIM已打包在%RP%盘,按任意键退出吧....
Pause >nul
EXIT
==============================
代码中的
move "%RP%\7pe\Users" %RP%\WIN7\
move "%RP%\7pe\windows" %RP%\WIN7\
move "%RP%\7pe\Program Files" %RP%\WIN7\
如果你的Win7PE是三个目录就和这个一样,是三句,如果是四个目录,就是四句,千万注意,别死搬硬套...
在此非常感谢chiannet
可以从这里下载试验用的驱动:http://www.vdisk.cn/down/index/10819733
做替身用的boot.wim可以用这里的,http://bbs.wuyou.net/viewthread.php?tid=211006&extra=page%3D2
以下是我DIY通用PE工具箱的成品链接地址:http://bbs.wuyou.net/viewthread.php?tid=213064&page=1&extra=page%3D1
Dism /Mount-Wim /WimFile:%RP%\wim\WIN7PE.WIM /index:1 /MountDir:%RP%\7pe
这句里面的数值1和版本有关,
对于32位的镜像bOOT.WIM,1---简易版,2----家庭普通版,3----家庭高级版,4---专业版,5----旗舰版
对于64位的镜像BOOT.WIM,1---家庭普通版,2----家庭高级版,3----专业版;4---旗舰版
比如,要给32位的简易版Win7pe集成驱动,那个数就填1,其实我们有时也分不清楚,如果运行出错,你改那个数就可以了,直到可以运行。